# My .cshrc file

set path=( /{,usr/{,local/}}{,s}bin /usr/{X11R6/bin,games} )

# directory stuff: cdpath/cd/back
set cdpath=(/sys /usr/src/{bin,sbin,usr.{bin,sbin},lib,libexec,share,local,games,gnu/{usr.bin,libexec,lib,games}})

setenv BLOCKSIZE 1m

alias	h	history
alias	hup	'kill -HUP `cat /var/run/\!$.pid`'
alias	j	jobs -l
alias	ll	ls -l

alias	x	exit
alias	z	suspend

alias	back	'set back="$old"; set old="$cwd"; cd "$back"; unset back; dirs'
alias	cd	'set old="$cwd"; chdir \!*'
alias	pd	pushd
alias	pd2	pushd +2
alias	pd3	pushd +3
alias	pd4	pushd +4
alias	tset	'set noglob histchars=""; eval `\tset -s \!*`; unset noglob histchars'
alias	cm	'ls -l /var/mail/erik'
alias	al	'tail -f /var/log/httpd/access_log'
umask 077

# this is dangerous if you're root 
set path = ( ${path} . )

# THESE LINES SHOULD BE EDITED TO SUIT YOUR USER/PREFERENCES
# %B makes text bold, %b turns it off
# %n is your login name
# %m is the hostname
# %c2 is the pwd, showing only two directories
# %h is the number in your command history
set	prompt = '%B%T%b (%h) %n@%m:[%c2]> '

alias pico	pico -z

# general UNIX
alias cl	clear
alias ls	ls -F
# process management
alias next	fg %+
alias prev	fg %-
alias mine	'ps -u $user | fgrep -v ps | fgrep -v fgrep'

alias pushd	'pushd .'

# shell settings that make alot of cool stuff happen
set	prompt3 = 'You meant %B%R%b, right? =>' \
	autoexpand \
	autolist \
	chase_symlinks \
	complete=enhance \
	correct=cmd \
	fignore=( .o .out \~ ) \
	filec \
	history=50 \
	host=`hostname` \
	listjobs=long \
	listlinks \
	listmaxrows=23 \
	nobeep \
	noclobber \
	notify \
	rmstar \
	savehist=200

# list 
set machines=(host1 host2 host3)
set names=(joeuser userjoe joeu )

# command completions
# by default, tcsh will use files to complete commands
# but you can program tcsh to complete commands differently
# a p means position, so p/1 means the first argument
# an n means the argument, so n/-l is completed by the list $names

if($?tcsh) then
complete rlogin \
        'p/1/$machines/' \
        'n/-l/$names/'

complete telnet \
	'p/1/$machines/' \

complete ssh \
	'p/1/$machines/' \

complete ping \
	'p/1/$machines/'

set cvs_cmds=(checkout commit add annotate edit remove watch wathchers)
complete cvs 'p/1/$cvs_cmds/'

endif

cd .